Microsoft Macro Assembler
Der Microsoft Macro Assembler (abgekürzt MASM) ist ein von Microsoft entwickelter Assembler für x86-Prozessoren. Er übersetzt Assemblerquelltext in ausführbaren, nativen Maschinencode.
Der Microsoft Macro Assembler entwickelte sich zeitweise zum meistbenutzten Assembler für die Entwicklung von MS-DOS-Programmen. Heutzutage ist MASM der bevorzugte Assembler für alle Microsoft-basierenden Betriebssysteme (wohl auch aufgrund des MASM32-SDK). Er ist in aktuellen Versionen in der Entwicklungsumgebung Microsoft Visual Studio (und Express) enthalten, es gibt ihn aber auch in einer separaten Download-Version. Die kostenlosen Versionen von MASM dürfen nicht für kommerzielle Zwecke verwendet werden. Zudem darf man sie nur zur Entwicklung für Microsoft-Betriebssysteme verwenden – alle anderen Betriebssysteme sind ausdrücklich durch die EULA (End-User License Agreement) ausgeschlossen.
Als kommerzieller Konkurrent zum Microsoft Macro Assembler behauptete sich besonders der Turbo Assembler von Borland.[1] Als kostenlose und freie Alternativen sind beispielsweise die beiden MASM kompatiblen Programme jWasm und UASM verfügbar. Außerdem gibt es noch den Netwide Assembler und Flat assembler mit eigner Syntax.
In der aktuellen Version 14.0 werden folgende Befehlssätze unterstützt: x86-Architektur, x87-fpu, MMX, 3DNow, SSE, SSE2, SSE3, SSSE3, SSE4.1, SSE4.2, SSE4.A, VMX, AVX, AVX2, AES-NI, CVT16, FMA3 und FMA4. Ab der Version 8.0 gibt es zwei Ausgaben unter derselben Versionsnummer, eine für die x86-32-Architektur und eine für die x86-64-Architektur.
Durch Microsofts Freigabe und Veröffentlichung des Quellcodes von MS-DOS 4.0[2] am 25. April 2024 ist MASM 5.10 mitsamt dem Microsoft C Compiler (Version 5.10), dessen Linker LINK.EXE (Version 3.65) und NMAKE.EXE (Version 1.00.05), sowie der dazugehörigen C Bibliothek als Binärcode öffentlich auf github verfügbar.[3]
Ausdrücke ähnlich den Hochsprachen
MASM verfügt über Ausdrücke, wie man sie aus C kennt. Diese erleichtern die Programmierung und helfen, den Quelltext übersichtlicher zu halten.
.while/.endw.repeat/.until.break.continue.if .elseif .else .endifinvoke(Funktionsaufruf)
Macros
Eine besonders hervorstechende Eigenschaft von MASM ist, wie der Name schon erahnen lässt, das äußerst mächtige Makrosystem. Mit ihm ist es sowohl möglich, Programmcode zu erstellen als auch Text zu verarbeiten. So ist es z. B. möglich, Konstrukte höherer Programmiersprachen wie „switch“ (Mehrfachauswahl in C) zu generieren.
Versionen
Der IBM Macro Assembler und der IBM Macro Assembler/2 waren OEM-Versionen des MASM. Obwohl MASM kein kommerzielles Produkt mehr ist, wird es von Microsoft weiterhin unterstützt. Die letzte MASM-Version, die als einzelnes Softwarepaket verkauft wurde, war die Version 6.11.
| MASM Version | Datum | Produkt | Bemerkungen |
|---|---|---|---|
| 1.0 | 1981 | (IBM) | für 8086 |
| 2.0 | 1984 | (Einzelprodukt) | für 8086/8087 |
| 3.0 | 1984 | (Einzelprodukt) | |
| 4.0 | 1985 | (Einzelprodukt) | |
| 5.0 | 1987 | (Einzelprodukt) | |
| 5.1 | 1988 | (Einzelprodukt) | OS/2-Unterstützung |
| 6.0 | 1991 | (Einzelprodukt) | 32bit- und OS/2-Unterstützung, mit der integrierten Entwicklungsumgebung Programmer’s WorkBench |
| 6.1 | 1992 | (Einzelprodukt) | |
| 6.11 | 1993 | (Einzelprodukt) | |
| 6.11d | 19.09.1995 | Windows 95 Driver Developer Kit | 6.11d ist die letzte Version für DOS |
| 6.12 | 27.08.1997 | (Update) | Unterstützung für Intel MMX-Instruktionen; ohne DOS-Extender |
| 6.13 | 05.12.1997 | (Update) | Unterstützung für AMD 3DNow-Instruktionen |
| 6.14 | 12.04.1999 | (Update) | Unterstützung für SSE |
| 6.15 | 2000 | Visual C++ 6.0 Processor Pack | Unterstützung für SSE2 |
| 7.0 | 2002 | Visual C++ .NET 2002 | |
| 7.1 | 2003 | Visual C++ .NET 2003 | |
| 8.0 | 2005 | Visual C++ 2005 | ab 8.0 zwei getrennte Versionen: x86-32(ml.exe) und x86-64(ml64.exe), SSE3/SSSE3 |
| 9.0 | 2008 | Visual C++ 2008 | SSE4.1/SSE4.2/SSE4.A |
| 10.0 | 2010 | Visual C++ 2010 | AVX/AES |
| 11.0 | 2011 | Visual C++ 2011 | AVX2/FMA/half-precision conversion |
| 12.0 | 2013 | Visual C++ 2013 | |
| 14.0 | 2019 | Visual Studio 2019 |
Beispielprogramme
Beispiel 1
Dieses Programm zeigt ein Dialogfenster mit dem Text "Hello World" an:
.686
.model flat,stdcall
option casemap:none
include windows.inc ; MASM32 SDK
include user32.inc ;
include kernel32.inc ;
;
includelib user32.lib ;
includelib kernel32.lib ;
StrA macro text:=<> ;macro
IFNDEF some_cntr ;
some_cntr = 0 ;
ELSE ;
some_cntr = some_cntr + 1 ;
ENDIF ;
;
IFNB <text> ;
.data ;
@CatStr(_stra_,%some_cntr) db text,0 ;
.code ;
% EXITM <OFFSET @CatStr(_stra_,%some_cntr)> ;
ELSE ;
echo string required! ;
EXITM <> ;
ENDIF ;
endm
.code
start:
;code
invoke MessageBox,NULL,StrA("Hello World"),StrA("Say hello"),MB_OK ;
invoke ExitProcess,NULL ;
;
end start
Beispiel 2
Dieses Beispielprogramm zeigt ein Fenster mit dem Text "Hello World!":
include masm32rt.inc ; MASM32 SDK
.data
ClassName db "WinClass",0
AppName db "Hello World App",0
Text db "Hello World!",0
.data?
msg MSG <>
wc WNDCLASSEX <>
.code
start:
mov wc.hInstance,rv(GetModuleHandle,NULL) ; fill WNDCLASSEX-struct
mov wc.cbSize,SIZEOF WNDCLASSEX ;
mov wc.style,CS_HREDRAW or CS_VREDRAW ;
mov wc.lpfnWndProc,OFFSET WndProc ;
mov wc.hbrBackground,rv(CreateSolidBrush,0FFFFFFh) ;
mov wc.lpszClassName,OFFSET ClassName ;
mov wc.hIcon,rv(LoadIcon,NULL,IDI_APPLICATION) ;
mov wc.hIconSm,eax ;
mov wc.hCursor,rv(LoadCursor,NULL,IDC_ARROW) ;
invoke RegisterClassEx,OFFSET wc
invoke CreateWindowEx,NULL\ ; create window
,OFFSET ClassName\ ;
,OFFSET AppName\ ;
,WS_OVERLAPPEDWINDOW\ ;
,CW_USEDEFAULT,CW_USEDEFAULT\;
,CW_USEDEFAULT,CW_USEDEFAULT\;
,NULL\ ;
,NULL\ ;
,wc.hInstance\ ;
,NULL ;
push eax ; tricky parameter passing ;)
invoke ShowWindow,DWORD ptr [esp+4],SW_SHOWNORMAL ;
call UpdateWindow ;
.while TRUE ; message loop
invoke GetMessage,OFFSET msg,NULL,0,0 ;
.break .if (!eax) ;
invoke TranslateMessage, OFFSET msg ;
invoke DispatchMessage, OFFSET msg ;
.endw ;
invoke ExitProcess,0 ; exit Program
WndProc proc hWnd:DWORD,uMsg:DWORD,wParam:DWORD,lParam:DWORD ; window call-back function
LOCAL ps:PAINTSTRUCT
LOCAL rect:RECT
.if uMsg == WM_DESTROY
invoke PostQuitMessage,NULL
.elseif uMsg == WM_PAINT
invoke BeginPaint,hWnd,ADDR ps ; paint text "Hello World!"
invoke GetClientRect,hWnd,ADDR rect ;
invoke DrawText,ps.hdc\ ;
,OFFSET Text\ ;
,SIZEOF Text\ ;
,ADDR rect\ ;
,DT_CENTER or DT_VCENTER or DT_SINGLELINE ;
invoke EndPaint,hWnd,ADDR ps ;
.else
invoke DefWindowProc,hWnd,uMsg,wParam,lParam
ret
.endif
xor eax,eax
ret
WndProc endp
end start
Beispiel 3
Dieses Programm demonstriert einen Algorithmus zur Bestimmung von Zeichenkettenlängen unter Zuhilfenahme von SSE2-Instruktionen:
include masm32rt.inc ; MASM32 SDK
.686p ; choose instruction set
.mmx ;
.xmm ;
szLenXmm proto :DWORD
.data
szTextA db "This string is 55 bytes long (without termination-zero)",0
.code
start:
invoke szLenXmm,OFFSET szTextA ; call szLenXmm
invoke MessageBox,0,OFFSET szTextA\
,cat$(chr$("string size = "),udword$(eax))\ ; generate title using macros
,MB_OK
invoke ExitProcess,0 ; exit program
szLenXmm proc lpString:DWORD ; determine string size
mov edx,lpString ; using XMM-instrutions
pxor xmm1,xmm1 ;
xor ecx,ecx ; PS: under extremely rarely
align 16 ; conditions this func. may
@@: movdqu xmm0,OWORD ptr [edx]; cause an access violation
pcmpeqb xmm0,xmm1 ;
pmovmskb eax,xmm0 ;
test eax,eax ;
lea ecx,[ecx+16] ;
lea edx,[edx+16] ;
jz @B ;
@@: lea ecx,[ecx-16] ;
bsf eax,eax ;
.if !ZERO? ;
lea ecx,[eax+ecx] ;
.endif ; str. size returns
mov eax,ecx ; through EAX
ret ;
szLenXmm endp ;
end start
Weblinks
- Download MASM 8.0 (für Visual C++ 2005 Express Edition)
- Microsoft Macro Assembler Reference MSDN
- MASM32 SDK
- MASM32 Support-Forum
- Deutscher Support und Beispielprogramme für MASM32
- jWasm
- UASM
Einzelnachweise
- ↑ DOS International 06/1989 S. 50 - MASM 5.1 oder TASM 1.0 Die Qual der Wahl
- ↑ https://cloudblogs.microsoft.com/opensource/2024/04/25/open-sourcing-ms-dos-4-0/ Open sourcing MS-DOS 4.0
- ↑ https://github.com/microsoft/MS-DOS/tree/main/v4.0/src/TOOLS MASM Version 5.10 mitsamt dem Microsoft C Compiler sowie weiterer Tools aber ohne IDE aus der Quellcodeveröffentlichung von MS-DOS 4.0